Time functions

systime ( )

1970-01-01 00:00:00 UTC (system epoch) 로부터 현재까지의 시간을 초 단위로 반환합니다.
이 값은 strftime 함수의 인수로 사용됩니다.

$ awk 'BEGIN { print systime() }' 
1524693474

mktime ( datespec )

systime 함수와 같이 system epoch 로부터의 시간을 초 단위로 반환하는데 차이점은 datespec 인수를 이용하여 특정일의 시간을 지정할 수 있습니다.

"YYYY MM DD HH MM SS"

년(YYYY) 4자리, 월(MM) from 1 to 12, 일(DD) from 1 to 31,
시(HH) from 0 to 23, 분(MM) from 0 to 59, 초(SS) from 0 to 60

# system epoch 로부터 2015년 6월 7일 8시 9분 10초 까지의 시간
$ awk 'BEGIN { 
    print mktime("2015 6 7 8 9 10") 
    print mktime("2015 06 07 08 09 10") 
}' 
1433632150
1433632150  # 같은 값
......................................

# '0' 일은 전달 마지막 일이 됩니다. ( 2 월이 28 일까지 인것을 알 수 있습니다 )
$ awk 'BEGIN{ print strftime("%Y-%m-%d %H:%M:%S", mktime("2017 3 0 0 0 0")) }'
2017-02-28 00:00:00

# 음수를 사용할 수도 있습니다.
$ awk 'BEGIN{ print strftime("%Y-%m-%d %H:%M:%S", mktime("2017 3 -1 0 0 0")) }'
2017-02-27 00:00:00

시간 차이 구하기

1 분은 60 초, 1 시간은 3600 초, 1 일은 86400 초 이므로

# 2017년 06월 07일 08시 09분 10초 로부터 현재까지의 시간 차이
$ awk 'BEGIN { print timediff( systime() - mktime("2017 6 7 8 9 10")) }
function timediff( d ) {
    day=86400; hour=3600; minute=60;
    return int( d / day ) " 일 " \
    int(( d % day ) / hour ) " 시간 " \
    int((( d % day ) % hour ) / minute ) " 분 " \
    int((( d % day ) % hour ) % minute ) " 초 " 
}'
323 일 2 시간 37 분 40 초

strftime ( [ format [, timestamp [, utc-flag ] ] ] )

strftime 함수는 포멧 스트링을 이용해 원하는 형식의 시간을 출력할 수 있습니다. systime, mktime 함수로부터 timestamp 값을 입력받아 사용할 수 있고, utc-flag 값이 non-null 이면 UTC 값이 적용됩니다.

UTC (Coordinated Universal Time, formerly GMT or Greenwich Mean Time).

$ awk 'BEGIN { print strftime() }' 
Thu Apr 26 07:07:05 KST 2018

$ awk 'BEGIN { 
    print strftime("%Y/%m/%d %H:%M:%S")
    print strftime("%Y/%m/%d %H:%M:%S", systime())
    print strftime("%Y/%m/%d %H:%M:%S", systime(), 1)   # UTC
}'
2018/04/26 07:03:37
2018/04/26 07:03:37
2018/04/25 22:03:37   # UTC
.............................................................

$ awk 'BEGIN { 
    print strftime("%Y/%m/%d %H:%M:%S", mktime("2015 6 7 8 9 10"))
    print strftime("%Y/%m/%d %H:%M:%S", mktime("2015 6 7 8 9 10"), 1)  # UTC
}'
2015/06/07 08:09:10
2015/06/06 23:09:10   # UTC

Format specifications & Descriptions

For systems that are not yet fully standards-compliant, gawk supplies a copy of strftime() from the GNU C Library. It supports all of the just-listed format specifications. If that version is used to compile gawk (see Installation), then the following additional format specifications are available: